В этой теме нет ответов

[tvrsh]

Скрипт показывают краткую информацию о нике при наведении на него мышкой.
Чтобы установить этот скрипт скопируйте код в Alt+R
Все.

;Thanx to hixxy for his regular expression code, if you have any regex querys/problems he's the guy to ask.
on ^*:hotlink:*:#:{
  if (($getnick($1) ison $chan) || ($getnick($1).checktheme ison $chan)) $&
    .timer.nickinfo -m 1 700 nickinfo $v1 $mouse.dx $mouse.dy $line($chan,0)
  halt
}
alias -l nickinfo {
  if (($2 == $mouse.dx) && ($3 == $mouse.dy) && ($4 == $line($active,0))) {
    var %n = Nick: $1, %a = Address: $iif($mid($address($1,0),3),$v1,Unknown), $&
      %i = Idle: $duration($nick($active,$1).idle), %c = Common Channels: $comchans($1), $&
      %w = $gettok($sorttok($calc($getwidth(%n) + 113) $calc($getwidth(%a) + 92) $calc($getwidth(%i) + 115) $&
      $calc($getwidth(%c) + 35),32,nr),1,32), %d = drawtext -r @nickinfo $rgb(text) tahoma 12
    window -dhkpn +fL @NickInfo $round($calc($2 - (%w / 2)),0) $calc($3 - 40) $calc(%w) 80
    drawfill -nr @nickinfo $rgb(face) $rgb(face) 0 0
    %d 93 5 %n
    %d 72 20 %a
    %d 95 35 %i
    %d 15 50 %c
    setlayer 0 @nickinfo
    window -o @nickinfo
    var %x = 1
    while (%x <= 255) {
      setlayer %x @nickinfo
      inc %x 1
    }
    checkmouse
  }
}
alias -l comchans {
  var %x = 1
  while ($comchan($1,%x)) {
    var %# = %# $+($remove($nick($v1,$1).pnick,$1),$v1)
    inc %x 1
  }
  return %#
}
alias -l getwidth return $width($1-,tahoma,12)
alias -l getnick {
  if ($prop == checktheme) noop $regex(nick,$1,/([a-z0-9Q`^-_{}|E]+)/iS)
  else noop $regex(nick,$1,/([a-z0-9Q`^-_[]{}|E]+)/iS)
  return $regml(nick,1)
}
alias -l closewin {
  if ($mouseinwin) checkmouse
  else {
    var %x = 255
    while (%x) {
      setlayer %x @nickinfo
      dec %x 1
    }
    window -c @nickinfo
  }
}
alias -l checkmouse {
  if ($mouseinwin) .timer.nickinfo_checkmouse -m 1 200 checkmouse
  else .timer.nickinfo_closewin -m 1 600 closewin
}
alias -l mouseinwin return $inrect($mouse.dx,$mouse.dy,$window(@nickinfo).dx,$window(@nickinfo).dy,$window(@nickinfo).dw,$window(@nickinfo).dh)
on *:active:@nickinfo:window -a $lactive

Nick Info v1.4 by jizzy
Downloaded at http://www.mircscrip...ts.php?cid=3409